8  ML Basis system

• Explicit file order: The order of files (and, hence, the order of evaluation) in the program is explicit. The MLBs semantics are structured in such a way that for any well-formed project, there will be exactly one possible interpretation of the project's syntax, static semantics, and dynamic semantics.
• Implicit dependencies: A source file (corresponding to a SML top-level declaration) is elaborated in the environment described by preceding declarations. It is not necessary to explicitly list the dependencies of a file.
• Scoping and renaming: MLBs provides mechanisms for limiting the scope of (i.e, hiding) and renaming identifiers.
• No file name convention: MLBs assumes no convention for finding the file that defines a module. (Conversely, to import a module, it's defining file must appear in the project.)

8.1  Syntax and semantics

8.2  Examples

Complete program: Suppose your complete program consists of the files file1.sml, ..., filen.sml, which depend upon libraries lib1.mlb, ..., libm.mlb.

(* import libraries *)
lib1.mlb
...
libm.mlb

(* program files *)
file1.sml
...
filen.sml

The bases denoted by lib1.mlb, ..., libm.mlb are merged (bindings of names in later bases take precedence over bindings of the same name in earlier bases), producing a basis in which file1.sml, ..., filen.sml are elaborated, possibly adding additional bindings to the basis.

Export filter: Suppose you only want to export certain structures, signatures, and functors from a collection of files.

local
  file1.sml
  ...
  filen.sml
in
  (* export filter here *)
  functor F
  structure S
end

While file1.sml, ..., filen.sml may declare top-level identifiers in addition to F and S, such names are not accessible to programs and libraries that import this .mlb.

Export filter with renaming: Suppose you want an export filter, but want to rename one of the modules.

local
  file1.sml
  ...
  filen.sml
in
  (* export filter, with renaming, here *)
  functor F
  structure S' = S
end

Note that functor F is an abbreviation for functor F = F, which simply exports an identifier under the same name.

Import filter: Suppose you only want to import a functor F from one library and a structure S from another library.

local
  lib1.mlb
in
  (* import filter here *)
  functor F
end
local
  lib2.mlb
in
  (* import filter here *)
  structure S
end
file1.sml
...
filen.sml

Import filter with renaming: Suppose you want to import a structure S from one library and another structure S from another library.

local
  lib1.mlb
in
  (* import filter, with renaming, here *)
  structure S1 = S
end
local
  lib2.mlb
in
  (* import filter, with renaming, here *)
  structure S2 = S
end
file1.sml
...
filen.sml

either-sigs.sml:

signature EITHER_GLOBAL =
  sig
    datatype ('a, 'b) either = Left of 'a | Right of 'b
    val &  : ('a -> 'c) * ('b -> 'c) -> ('a, 'b) either -> 'c
    val && : ('a -> 'c) * ('b -> 'd) -> ('a, 'b) either -> ('c, 'd) either
  end

signature EITHER =
  sig
    include EITHER_GLOBAL
    val isLeft  : ('a, 'b) either -> bool
    val isRight : ('a, 'b) either -> bool
    ...
  end

either-strs.sml:

structure Either : EITHER =
  struct
    datatype ('a, 'b) either = Left of 'a | Right of 'b
    fun f & g = fn x =>
      case x of Left z => f z | Right z => g z
    fun f && g = fn x =>
      ((Left o f) & (Right o g)) x
    fun isLeft x = ((fn _ => true) & (fn _ => false)) x
    fun isRight x = (not o isLeft) x
    ...
  end
structure EitherGlobal : EITHER_GLOBAL = Either

either-infixes.sml:

infixr 3 & &&

either-open.sml:

open EitherGlobal

either.mlb:

local
  (* import Basis Library *)
  basis.mlb

  either-sigs.sml
  either-infixes.sml
  either-strs.sml
in
  signature EITHER
  structure Either
  either-infixes.sml
  either-open.sml
end

8.3  Path maps

8.4  Available libraries

8.5  Annotations

allowExport {false|true}

 
If true, allow the _export expression form of Section 6.2 to appear in imported source files.

allowImport {false|true}

 
If true, allow the _import expression form of Section 6.1 to appear in imported source files.

forceUsed

 
Force all identifiers in the basis denoted by the body of the ann to be considered used; use in conjunction with warnUnused true.

sequenceUnit {false|true}

 
If true, then in the sequence expression (e1; e2), it is a type error if e1 is not of type unit. This can be helpful in detecting curried applications that are mistakenly not fully applied. To silence spurious errors, you can use ignore e1.

warnMatch {true|false}

 
Report nonexhaustive and redundant matches.

warnUnused {false|true}

 
Report unused identifiers.

8.5.1  Examples

local
  $(GEN_ROOT)/gen-lib.mlb

  ann "warnMatch false" in
    foo.gen.sml
  end
in
  signature FOO
  structure Foo
end

ann 
  "sequenceUnit false"
  "warnMatch true"
  "warnUnused true" "forceUsed"
in
  local
    file1.sml
    ...
    filen.sml
  in
    functor F1
    ...
    signature S1
    ...
    structure SN
    ...
  end
end